--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/m4/sysexits.m4	Sun Aug 16 17:16:49 2009 +0000
@@ -0,0 +1,43 @@
+# sysexits.m4 serial 4
+dnl Copyright (C) 2003, 2005, 2007 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([gl_SYSEXITS],
+[
+  AC_CHECK_HEADERS_ONCE([sysexits.h])
+  if test $ac_cv_header_sysexits_h = yes; then
+    HAVE_SYSEXITS_H=1
+    gl_CHECK_NEXT_HEADERS([sysexits.h])
+    AC_TRY_COMPILE([#include <sysexits.h>],
+      [switch (0)
+       {
+       case EX_OK:
+       case EX_USAGE:
+       case EX_DATAERR:
+       case EX_NOINPUT:
+       case EX_NOUSER:
+       case EX_NOHOST:
+       case EX_UNAVAILABLE:
+       case EX_SOFTWARE:
+       case EX_OSERR:
+       case EX_OSFILE:
+       case EX_CANTCREAT:
+       case EX_IOERR:
+       case EX_TEMPFAIL:
+       case EX_PROTOCOL:
+       case EX_NOPERM:
+       case EX_CONFIG:
+         break;
+       }
+      ],
+      [SYSEXITS_H=],
+      [SYSEXITS_H=sysexits.h])
+  else
+    HAVE_SYSEXITS_H=0
+    SYSEXITS_H=sysexits.h
+  fi
+  AC_SUBST([HAVE_SYSEXITS_H])
+  AC_SUBST([SYSEXITS_H])
+])